# GIMUD - Graphical Interface Multi User Dungeon
# aldo.npc: Datenbank für den Schuhverkäufer Aldo

Name = "Aldo"
Outfit = (128,40-37-116-76)
Home = [32953,32110,6]
Radius = 2

Behaviour = {
ADDRESS,"hello$",! -> "Just great, another ... 'customer'. Hello, %N."
ADDRESS,"hi$",!    -> *
ADDRESS,!          -> Idle
BUSY,"hello$",!    -> "Yes, yes, I can only talk to one after the other! You will have to wait, %N.", Queue
BUSY,"hi$",!       -> *
BUSY,!             -> NOP
VANISH,!           -> "Yeah, get lost."

"bye"       -> "That's music in my ears.", Idle
"name"      -> "I'm Aldo. No one calls me 'lucky Aldo' though, guess why!"
"job"       -> "I am a salesman, I sell headgear ... uhm ... oh well, and shoes."
"time"      -> "Is it time for lunch already? Hey, stop making fun of me!"
"king"      -> "One day I will sell the king a pair of shoes made by me and will get out of that stinky hole I live in and my family will never find me. HE, HE!"
"tibianus"  -> *
"army"      -> "So many feet ... so many ... a nightmare!"
"ferumbras" -> "Can't be worse than my wife."
"wife"      -> "Leave me alone with her while I am working at least. My only pleasure around here!"
"excalibug" -> "I have other stuff to worry about, like paying my bills."
"bill"      -> "Yes, I have to pay o lot of bills, and some georges, and a john, and several steves."
"thais"     -> "I will never in my life make it there."
"tibia"     -> "I doubt I will ever see much of it. It's like i am cursed to haunt this site here for the rest of my life."
"carlin"    -> "A city ruled by women!? Could anything be worse?"
"amazon"    -> "I heard that chicks wear some revealing pieces of armor!"
"news"      -> "Hey, I am a man. Look for some women to share gossip."
"rumour"    -> *
"rumor"     -> *
"hugo"      -> "My boss, an evil slaver of good people like me."

"offer"           -> "I am damned to sell headgear, trousers, and shoes for the rest of my life."
"goods"           -> *
"do","you","sell" -> *
"do","you","have" -> *
"headgear"        -> "We have leather helmets and studded helmets."
"shoes"           -> "<sigh> We sell leather boots and sandals."
"trouser"         -> "We offer leather legs and studded legs."

"leather","helmet" -> Type=3355, Amount=1, Price=12, "Do you want to buy a leather helmet for %P gold?", Topic=1
"studded","helmet" -> Type=3376, Amount=1, Price=63, "Do you want to buy a studded helmet for %P gold?", Topic=1
"sandals"          -> Type=3551, Amount=1, Price=2,  "Do you want to buy one of my wonderful sandals for %P gold?", Topic=1
"leather","boot"   -> Type=3552, Amount=1, Price=2,  "Do you want to buy one of my wonderful leather boots for %P gold?", Topic=1
"leather","legs"   -> Type=3559, Amount=1, Price=10, "Do you want to buy leather legs for %P gold?", Topic=1
"studded","legs"   -> Type=3362, Amount=1, Price=60, "Do you want to buy studded legs for %P gold?", Topic=1

%1,1<%1,"leather","helmet" -> Type=3355, Amount=%1, Price=12*%1, "Do you want to buy %A leather helmets for %P gold?", Topic=1
%1,1<%1,"studded","helmet" -> Type=3376, Amount=%1, Price=63*%1, "Do you want to buy %A studded helmets for %P gold?", Topic=1
%1,1<%1,"sandals"          -> Type=3551, Amount=%1, Price=2*%1,  "Do you want to buy %A of my wonderful sandals for %P gold?", Topic=1
%1,1<%1,"leather","boot"   -> Type=3552, Amount=%1, Price=2*%1,  "Do you want to buy %A of my wonderful leather boots for %P gold?", Topic=1
%1,1<%1,"leather","legs"   -> Type=3559, Amount=%1, Price=10*%1, "Do you want to buy %A leather legs for %P gold?", Topic=1
%1,1<%1,"studded","legs"   -> Type=3362, Amount=%1, Price=60*%1, "Do you want to buy %A studded legs for %P gold?", Topic=1

Topic=1,"yes",CountMoney>=Price -> "Here. I hope that's it now.", DeleteMoney, Create(Type)
Topic=1,"yes"                   -> "At last, someone poorer than me."
Topic=1,"no"                    -> "Good decision!"
}
