# GIMUD - Graphical Interface Multi User Dungeon
# quero.npc: Datenbank für den Barden Quero

Name = "Quero"
Outfit = (128,55-30-23-115-0)
Home = [32390,32220,7]
Radius = 1

Behaviour = {
ADDRESS,"hello$",! -> "Welcome %N! Can I help you?"
ADDRESS,"hi$",!    -> *
ADDRESS,!          -> Idle
BUSY,"hello$",!    -> "Sorry, I am already talking to someone, %N.", Queue
BUSY,"hi$",!       -> *
BUSY,!             -> NOP
VANISH,!           -> "Good bye."

"bye"       -> "Good bye.", Idle
"farewell"  -> *
"job"       -> "I make instruments and sometimes I'm wandering through the lands of Tibia as a bard."
"name"      -> "My name is Quero."
"time"      -> "Sorry, I don't know what time it is."

"music"     -> "I love the music of the elves."
"elf"       -> "They live in the northeast of Tibia."
"elves"     -> *
"bard"      -> "Selling instruments isn't enough to live on and I love music. That's why I wander through the lands from time to time."

"benjamin"  -> "He's nice."

"offer"           -> "You can buy a lyre, lute, drum, and simple fanfare."
"goods"           -> *
"do","you","sell" -> *
"do","you","have" -> *
"instrument"      -> *

"lyre"             -> Type=2949, Amount=1, Price=120, "Do you want to buy a lyre for %P gold?", Topic=1
"lute"             -> Type=2950, Amount=1, Price=195, "Do you want to buy a lute for %P gold?", Topic=1
"drum"             -> Type=2952, Amount=1, Price=140, "Do you want to buy a drum for %P gold?", Topic=1
"simple","fanfare" -> Type=2954, Amount=1, Price=150, "Do you want to buy a simple fanfare for %P gold?", Topic=1

%1,1<%1,"lyre"             -> Type=2949, Amount=%1, Price=120*%1, "Do you want to buy %A lyres for %P gold?", Topic=1
%1,1<%1,"lute"             -> Type=2950, Amount=%1, Price=195*%1, "Do you want to buy %A lutes for %P gold?", Topic=1
%1,1<%1,"drum"             -> Type=2952, Amount=%1, Price=140*%1, "Do you want to buy %A drums for %P gold?", Topic=1
%1,1<%1,"simple","fanfare" -> Type=2954, Amount=%1, Price=150*%1, "Do you want to buy %A simple fanfares for %P gold?", Topic=1

Topic=1,"yes",CountMoney>=Price -> "Here you are.", DeleteMoney, Create(Type)
Topic=1,"yes"                   -> "Come back, when you have enough money."
Topic=1                         -> "Hmm, but next time."
}
