# GIMUD - Graphical Interface Multi User Dungeon

Name = "Bron"
Outfit = (143,95-94-132-86-2)
Home = [32366,31628,7]
Radius = 2

Behaviour = {
ADDRESS,"hello$",QuestValue(17532)=6,! -> "Oh no! Was that really me? This is so embarassing, I have no idea what has gotten into me. Was that the fighting spirit you gave me?", SetQuestValue(17532,7), Topic=4
ADDRESS,"hi$",QuestValue(17532)=6,!    -> *
ADDRESS,"hello$",! -> "Welcome to my humble hut, %N."
ADDRESS,"hi$",!    -> *
ADDRESS,!          -> Idle
BUSY,"hello$",!    -> "Wait, %N.", Queue
BUSY,"hi$",!       -> *
BUSY,!             -> NOP
VANISH,!           -> "Bye."

"bye"            -> "Bye, %N.", Idle
"farewell"       -> *

"violence",QuestValue(17532)=0 -> "Convincing Ajax that it is not always necessary to use brute force... this would be such an achievement. Definitely a hard task though. ...",
								"Listen, I simply have to ask, maybe a stranger can influence him better than I can. Would you help me with my brother?", Topic=1
Topic=1,"yes" -> "Really! That is such an incredibly nice offer! I already have a plan. You have to teach him that sometimes words are stronger than fists. ...",
				"Maybe you can provoke him with something to get angry, like saying... 'MINE!' or something. But beware, I'm sure that he will try to hit you. ...",
				"Don't do this if you feel weak or ill. He will probably want to make you leave by using violence, but just stay strong and refuse to give up. ...",
				"If he should ask what else is necessary to make you leave, tell him to 'say please'. Afterwards, do leave and return to him one hour later. ...",
				"This way he might learn that violence doesn't always help, but that a friendly word might just do the trick. ...",
				"Have you understood everything I told you and are really willing to take this risk?", Topic=2
Topic=1 -> "Maybe another time."
Topic=2,"yes" -> "You are indeed not only well educated, but also very courageous. I wish you good luck, you are my last hope.", SetQuestValue(17532,1)
Topic=2 -> "Maybe another time."

"Brother","is","right","Fist","not","always","good",QuestValue(17532)=3 -> "Oh! He really said that? I am so proud of you, %N. These are really good news. Everything would be great... if only there wasn't this person near my house.", SetQuestValue(17532,4)
"person",QuestValue(17532)=4 -> "This... person... makes me want to... say something bad... must... control myself. <sweats> I really don't know what to do anymore....",
								"I wonder if Ajax has an idea. Could you ask him about Gelagos?", Topic=3
"gelagos",QuestValue(17532)=4 -> *
"gelagos" -> "This... person... makes me want to... say something bad... must... control myself."
Topic=3,"yes" -> "Again, I have to thank you for your selfless offer to help me. I hope that Ajax can come up with something, now that he has experienced the power of words.", SetQuestValue(17532,5)
Topic=3 -> "Maybe another time."

"fighting","spirit",QuestValue(17532)=5,Count(5884)>=1 -> "Fighting spirit? What am I supposed to do with this fi... - oh! I feel strange... ME MIGHTY! ME WILL CHASE OFF ANNOYING KIDS!GROOOAARR!! RRRRRRRRRRRRAAAAAAAGE!!", DeleteAmount(5884, 1), SetQuestValue(17532,6), Idle
"fighting","spirit" -> "No, no, no. I don't need any fighting spirit never."

Topic=4,"yes" -> "I'm impressed... I am sure this was Ajax' idea. I would love to give him a present, but if I leave my hut to gather ingredients, he will surely notice. ...",
				"Would you maybe help me again, one last time, my friend? I assure you that your efforts will not be in vain.", Topic=5
Topic=4 -> "Of course not you my educated friend. I can't believe how this happened. I would love to give Ajax a present, but if I leave my hut to gather ingredients, he will surely notice. ...",
			"Would you maybe help me again, one last time, my friend? I assure you that your efforts will not be in vain.", Topic=5

"help",QuestValue(17532)=7 -> "Oh, you came to help me to make a present for Ajax?", Topic=5
"present",QuestValue(17532)=7 -> *
Topic=5,"yes" -> "Great! You see, I really would love to sew a nice shirt for him. I just need a few things for that, so please listen closely: ...",
				"He loves green and red, so I will need about 50 pieces of red cloth - like the material heroes make their capes of - and 50 pieces of the green cloth Djinns like. ...",
				"Secondly, I need about 10 rolls of spider silk yarn. I think mermaids can yarn silk of large spiders to create a smooth thread. ...",
				"The only remaining thing needed would be a bottle of warrior's sweat to spray it over the shirt... he just loves this smell. ...",
				"Have you understood everything I told you and are willing to handle this task?", Topic=6
Topic=5 -> "Hmmm. If you wish to help another time to make a present I will be waiting for you."
Topic=6,"yes" -> "Thank you, my friend! Come back to me once you have collected 50 pieces of red cloth and 50 pieces of green cloth.", SetQuestValue(17532,8)
Topic=6 -> "Hmmm. If you wish to help another time to make a present I will be waiting for you."
"cloth",QuestValue(17532)=8 -> "Have you really managed to fulfill the task and brought me 50 pieces of red cloth and 50 pieces of green cloth?", Topic=7
Topic=7,"yes",Count(5911)>=50,Count(5910)>=50 -> "Terrific! I will start to trim it while you gather 10 rolls of spider silk. I'm sure that Ajax will love it.", DeleteAmount(5911,50), DeleteAmount(5910,50), SetQuestValue(17532,9)
Topic=7,"yes"                     -> "Sorry, you do not have so many."
Topic=7                           -> "Maybe another time."

"rolls","of","spider","silk",QuestValue(17532)=9 -> "Oh, did you bring 10 rolls of spider silk yarn for me?", Topic=8
Topic=8,"yes",Count(5886)>=10 -> "I'm impressed! You really managed to get spider silk yarn for me! I will immediately start to work on this shirt. Please don't forget to bring me warrior's sweat!", DeleteAmount(5886,10), SetQuestValue(17532,10)
Topic=8,"yes"                     -> "Sorry, you do not have so many."
Topic=8                           -> "Maybe another time."

"sweat",QuestValue(17532)=10 -> "Were you able to get hold of a flask with pure warrior's sweat?", Topic=9
Topic=9,"yes",Count(5885)>=1 -> "Good work, %N! Now I can finally finish this present for Ajax. Because you were such a great help, I have also a present for you. Will you accept it?", DeleteAmount(5885,1), SetQuestValue(17532,11), Topic=10
Topic=9,"yes"                     -> "Sorry, you do not have it."
Topic=9                           -> "Maybe another time."

"present",QuestValue(17532)=11 -> "Because you were such a great help, I have also a present for you. Will you accept it?", Topic=10
"help",QuestValue(17532)=11 -> *
Topic=10,"yes"                     -> "I have kept this traditional barbarian wig safe for many years now. It is now yours! I hope you will wear it proudly, friend.", AddOutfitAddon(147,2), AddOutfitAddon(143,2), SetQuestValue(17532,12), EffectOpp(13)
Topic=10                           -> "Okey, ask for it when you feel ready, friend."

"axe",QuestValue(17532)=17      -> "I know it is you who helped with the present for me from my brother Ajax. Thank you! Wear your axe proudly!"
"addon",QuestValue(17532)=17 -> *
"wig",QuestValue(17532)>11         -> "I hope you will wear the traditional barbarian wig proudly, friend."
"addon",QuestValue(17532)>11 -> *

}
